【剑仙教程】tc炫舞，脚本教程。

剑仙十号

先使用大漠综合工具做字库。
点阵的个头，做得越大越好。
点阵的特征，越明显越好。
相反的，
点阵的个头小做得很小，做好的字库就差，误识别率很高。
点阵的特征不明显，做好字库也是差，识别率低。
把tc炫舞 拖动到Flashplayer9 中，就可以启动跳舞的游戏。
Ult_X,Ult_Y,客户区左上角的X,Y座标。 User,客户区。 top left corner,左上角。



var 线程ID1,线程开关
function tc炫舞()
  线程开关 = 真
  var hwnd=windowfind("Adobe Flash Player 9","ShockwaveFlash")
  if(hwnd==0)
    messagebox("游戏未启动。")
    threadclose(线程ID1)
  end
  
  windowactivate(hwnd)
  窗口设置大小(hwnd,558,458)
  
  var dm=com("dm.dmsoft")//建立大漠对象.
  dm.SetPath("D:\\1编程\\1大漠\\dm_字库图片")
  dm.SetDict(0,"tc炫舞2016.txt")
  var dm_ret = dm.BindWindow(hwnd,"gdi","windows","windows",0)
  sleep(100)
  
  while(线程开关)//主循环。
   
    //第一部分：先用大漠完成识字。
    var M=dm.Ocr(78,214,516,291,"ff0000-000000",1.0)
    sleep(100)
    if(M!= "")
      var L=strlen(M)
      traceprint("找到的方向键为:"&M)
      staticsettext("标签2",M)
      sleep(30)
      
      //第二部分：完成所有的方向键。//嵌套循环1。
      for(var i=0;i<L;i++)
        var ret=strsub(M,i,i+1)
        select(ret)
          case "↑"
          dm.KeyPress(38)
          case "↓"
          dm.KeyPress(40)
          case "←"
          dm.KeyPress(37)
          case "→"
          dm.KeyPress(39)
        end
        sleep(20)
      end
      traceprint("已经完成方向键的按键。")
      sleep(100)
      
      //第三部分：定点比色，判断小球是否来到P点。//嵌套循环2。
      //var返回值=cmpcolor(442,584,"B8CFE9",1.0)//不匹配,返回值=-1
      //traceprint(返回值)
      //var返回值=cmpcolor(247,814,"B8CFE9",1.0)//匹配成功,返回值=0
      //traceprint(返回值)
      while(线程开关)
        if(dm.CmpColor(357,160,"FFFFFF-000000",0.9)==0)//匹配成功,返回值 = 0.证明小球来到了时间槽。
          sleep(35)
          dm.KeyPress(32)
          break
        end
        sleep(10)
      end
      traceprint("已经完成P点的按键。")
      sleep(300)
      
      //第四部分：用定点比色，判断新循环是否开始了。//嵌套循环3.
      while(线程开关)
        if(dm.CmpColor(106,155,"FFFFFF-000000",0.9)==0)//匹配成功,返回值 = 0.证明小球重新开始。
          break
        end
        sleep(10)
      end
    end
    traceprint("已经开始新的循环。")
    sleep(100)
  end//主循环尾。
  
  dm.UnBindWindow()
  sleep(100)
  traceprint("脚本已经停止。")
end
function 启动_热键()
  线程ID1=threadbegin("tc炫舞","")
end
function 终止_热键()
  线程开关 = 假
end
功能 按钮_窗口绑定_点击()
  线程ID1=threadbegin("tc炫舞","")
结束
功能 按钮_解除绑定_点击()
  线程开关 = 假
结束

东月山

嘿嘿,感谢楼主分享！！...